46b93b9d22
* Implement memory profiler, optimize memory usage, modify code indent * Implement memory.grow and limit heap space base offset to 1G; modify iwasm build type to Release and 64 bit by default * Add a new extension library: connection * Fix bug of reading magic number and version in big endian platform * Re-org platform APIs: move most platform APIs from iwasm to shared-lib * Enhance wasm loader to fix some security issues * Fix issue about illegal load of EXC_RETURN into PC on stm32 board * Updates that let a restricted version of the interpreter run in SGX * Enable native/app address validation and conversion for wasm app * Remove wasm_application_exectue_* APIs from wasm_export.h which makes confused * Refine binary size and fix several minor issues Optimize interpreter LOAD/STORE opcodes to decrease the binary size Fix issues when using iwasm library: _bh_log undefined, bh_memory.h not found Remove unused _stdin/_stdout/_stderr global variables resolve in libc wrapper Add macros of global heap size, stack size, heap size for Zephyr main.c Clear compile warning of wasm_application.c * Add more strict security checks for libc wrapper API's * Use one libc wrapper copy for sgx and other platforms; remove bh_printf macro for other platform header files * Enhance security of libc strcpy/sprintf wrapper function * Fix issue of call native for x86_64/arm/mips, add module inst parameter for native wrapper functions * Remove get_module_inst() and fix issue of call native * Refine wgl lib: remove module_inst parameter from widget functions; move function index check to runtime instantiate * Refine interpreter call native process, refine memory boudary check * Fix issues of invokeNative function of arm/mips/general version * Add a switch to build simple sample without gui support * Add BUILD_TARGET setting in makefile to replace cpu compiler flags in source code * Re-org shared lib header files, remove unused info; fix compile issues of vxworks * Add build target general * Remove unused files * Update license header * test push * Restore file * Sync up with internal/feature * Sync up with internal/feature * Rename build_wamr_app to build_wasm_app * Fix small issues of README * Enhance malformed wasm file checking Fix issue of print hex int and implement utf8 string check Fix wasi file read/write right issue Fix minor issue of build wasm app doc * Sync up with internal/feature * Sync up with internal/feature: fix interpreter arm issue, fix read leb issue * Sync up with internal/feature * Fix bug of config.h and rename wasi config.h to ssp_config.h * Sync up with internal/feature * Import wamr aot * update document * update document * Update document, disable WASI in 32bit * update document * remove files * update document * Update document * update document * update document * update samples * Sync up with internal repo
85 lines
2.2 KiB
ArmAsm
85 lines
2.2 KiB
ArmAsm
/*
|
|
* Copyright (C) 2019 Intel Corporation. All rights reserved.
|
|
* SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
|
|
*/
|
|
.text
|
|
.align 2
|
|
.global invokeNative
|
|
.type invokeNative,function
|
|
|
|
/*
|
|
* Arguments passed in:
|
|
*
|
|
* r0 function ptr
|
|
* r1 argv
|
|
* r2 argc
|
|
*/
|
|
|
|
invokeNative:
|
|
push {r4, r5, r6, r7}
|
|
push {lr}
|
|
mov ip, r0 /* ip = function ptr */
|
|
mov r4, r1 /* r4 = argv */
|
|
mov r5, r2 /* r5 = argc */
|
|
|
|
cmp r5, #1 /* at least one argument required: exec_env */
|
|
blt return
|
|
|
|
mov r6, #0 /* increased stack size */
|
|
|
|
ldr r0, [r4] /* r0 = argv[0] = exec_env */
|
|
add r4, r4, #4 /* r4 += 4 */
|
|
cmp r5, #1
|
|
beq call_func
|
|
|
|
ldr r1, [r4] /* r1 = argv[1] */
|
|
add r4, r4, #4
|
|
cmp r5, #2
|
|
beq call_func
|
|
|
|
ldr r2, [r4] /* r2 = argv[2] */
|
|
add r4, r4, #4
|
|
cmp r5, #3
|
|
beq call_func
|
|
|
|
ldr r3, [r4] /* r3 = argv[3] */
|
|
add r4, r4, #4
|
|
cmp r5, #4
|
|
beq call_func
|
|
|
|
sub r5, r5, #4 /* argc -= 4, now we have r0 ~ r3 */
|
|
|
|
/* Ensure address is 8 byte aligned */
|
|
lsl r6, r5, #2 /* r6 = argc * 4 */
|
|
mov r7, #7
|
|
add r6, r6, r7 /* r6 = (r6 + 7) & ~7 */
|
|
bic r6, r6, r7
|
|
add r6, r6, #4 /* +4 because odd(5) registers are in stack */
|
|
mov r7, sp
|
|
sub r7, r7, r6 /* reserved stack space for left arguments */
|
|
mov sp, r7
|
|
|
|
mov lr, r2 /* save r2 */
|
|
loop_args: /* copy left arguments to stack */
|
|
cmp r5, #0
|
|
beq call_func1
|
|
ldr r2, [r4]
|
|
add r4, r4, #4
|
|
str r2, [r7]
|
|
add r7, r7, #4
|
|
sub r5, r5, #1
|
|
b loop_args
|
|
|
|
call_func1:
|
|
mov r2, lr /* restore r2 */
|
|
|
|
call_func:
|
|
blx ip
|
|
add sp, sp, r6 /* restore sp */
|
|
|
|
return:
|
|
pop {r3}
|
|
pop {r4, r5, r6, r7}
|
|
mov lr, r3
|
|
bx lr
|